First implementation

It seems to work but I think the ticker value returned
by the remote call is wrong. Maybe I'm calling the wrong
endpoint ¯\_(ツ)_/¯ I don't know trying to work it out

subprojects/curlcpp.wrap

@@ -0,0 +1,7 @@
+[wrap-git]
+url = https://github.com/JosephP91/curlcpp.git
+revision = cb426314da69a6a66ac50437362844e6333ca5a9
+patch_directory = curlcpp
+
+[provide]
+dependency_names = curlcpp-1.4

subprojects/packagefiles/curlcpp/meson.build

@@ -0,0 +1,38 @@
+project('curlcpp', 'cpp',
+  version: '1.4',
+  meson_version: '>=0.49.2',
+  default_options: ['buildtype=release', 'cpp_std=c++11', 'b_ndebug=if-release'],
+  license: 'MIT',
+)
+
+curl_dep = dependency('libcurl', version: '>=7.28.0')
+public_incl = include_directories('include')
+subdir('src')
+
+if not meson.is_subproject()
+  install_headers(
+	'include/cookie.h',
+	'include/cookie_date.h',
+	'include/cookie_datetime.h',
+	'include/cookie_time.h',
+	'include/curl_config.h',
+	'include/curl_cookie.h',
+	'include/curl_easy.h',
+	'include/curl_easy_info.h',
+	'include/curl_exception.h',
+	'include/curl_form.h',
+	'include/curl_global.h',
+	'include/curl_header.h',
+	'include/curl_info.h',
+	'include/curl_interface.h',
+	'include/curl_ios.h',
+	'include/curl_multi.h',
+	'include/curl_option.h',
+	'include/curl_pair.h',
+	'include/curl_receiver.h',
+	'include/curl_sender.h',
+	'include/curl_share.h',
+	'include/curl_utility.h',
+	subdir: meson.project_name(),
+  )
+endif

subprojects/packagefiles/curlcpp/src/meson.build

@@ -0,0 +1,24 @@
+curlcpp = library(meson.project_name(),
+  'curl_easy.cpp',
+  'curl_header.cpp',
+  'curl_global.cpp',
+  'curl_form.cpp',
+  'curl_multi.cpp',
+  'curl_share.cpp',
+  'curl_info.cpp',
+  'curl_cookie.cpp',
+  'curl_exception.cpp',
+  'cookie.cpp',
+  'cookie_date.cpp',
+  'cookie_time.cpp',
+  'cookie_datetime.cpp',
+  dependencies: [curl_dep],
+  include_directories: public_incl,
+  install: (not meson.is_subproject() or get_option('default_library')=='shared')
+)
+
+curlcpp_dep = declare_dependency(
+  link_with: curlcpp,
+  include_directories: public_incl,
+  dependencies: curl_dep.partial_dependency(includes: true),
+)

subprojects/packagefiles/simdjson/meson.build

@@ -0,0 +1,36 @@
+project('simdjson', 'cpp',
+  version: '1.0.2',
+  meson_version: '>=0.49.2',
+  default_options: ['buildtype=release', 'cpp_std=c++11', 'b_ndebug=if-release'],
+  license: 'Apache',
+)
+
+public_incl = include_directories('include')
+
+compiler_opts = []
+if not get_option('simdjson_implementation_haswell')
+  compiler_opts += ['-DSIMDJSON_IMPLEMENTATION_HASWELL=0']
+endif
+if not get_option('simdjson_implementation_westmere')
+  compiler_opts += ['-DSIMDJSON_IMPLEMENTATION_WESTMERE=0']
+endif
+if not get_option('simdjson_implementation_arm64')
+  compiler_opts += ['-DSIMDJSON_IMPLEMENTATION_ARM64=0']
+endif
+if not get_option('simdjson_implementation_fallback')
+  compiler_opts += ['-DSIMDJSON_IMPLEMENTATION_FALLBACK=0']
+endif
+if not get_option('simdjson_exceptions')
+  compiler_opts += ['-DSIMDJSON_EXCEPTIONS=0']
+endif
+thread_dep = dependency('threads', required: get_option('simdjson_enable_threads'))
+if thread_dep.found()
+  compiler_opts += ['-DSIMDJSON_THREADS_ENABLED=1']
+endif
+
+cpp_comp = meson.get_compiler('cpp')
+if cpp_comp.get_argument_syntax() == 'gcc' and (host_machine.cpu_family() == 'x86_64' or host_machine.cpu_family() == 'x86')
+  compiler_opts += ['-mno-avx256-split-unaligned-load', '-mno-avx256-split-unaligned-store']
+endif
+
+subdir('src')

subprojects/packagefiles/simdjson/meson_options.txt

@@ -0,0 +1,6 @@
+option('simdjson_implementation_haswell', type: 'boolean', value: true, description: 'Include the haswell implementation')
+option('simdjson_implementation_westmere', type: 'boolean', value: true, description: 'Include the westmere implementation')
+option('simdjson_implementation_arm64', type: 'boolean', value: true, description: 'Include the arm64 implementation')
+option('simdjson_implementation_fallback', type: 'boolean', value: true, description: 'Include the fallback implementation')
+option('simdjson_exceptions', type: 'boolean', value: true, description: 'Enable simdjson\'s exception-throwing interface')
+option('simdjson_enable_threads', type: 'feature', value: 'auto', description: 'Link with thread support')

subprojects/packagefiles/simdjson/src/meson.build

@@ -0,0 +1,12 @@
+simdjson = static_library(meson.project_name(),
+  'simdjson.cpp',
+  include_directories: public_incl,
+  install: not meson.is_subproject(),
+  cpp_args: compiler_opts,
+  dependencies: [thread_dep],
+)
+
+simdjson_dep = declare_dependency(
+  link_with: simdjson,
+  include_directories: public_incl,
+)

subprojects/simdjson.wrap

@@ -0,0 +1,7 @@
+[wrap-git]
+url = https://github.com/simdjson/simdjson.git
+revision = 17f3148ac73da9895bdbd26ed2c4848fd77571a8
+patch_directory = simdjson
+
+[provide]
+dependency_names = simdjson-1.0.2

subprojects/wrenpp

@@ -0,0 +1 @@
+Subproject commit edd5f27ab2013e7d768fead766274b1a9eab6075