forked from mirror/libbpg
libbpg-0.9.6
This commit is contained in:
parent
3035b41edf
commit
35a8402710
248 changed files with 232891 additions and 100 deletions
68
x265/source/cmake/CMakeASM_YASMInformation.cmake
Normal file
68
x265/source/cmake/CMakeASM_YASMInformation.cmake
Normal file
|
|
@ -0,0 +1,68 @@
|
|||
set(ASM_DIALECT "_YASM")
|
||||
set(CMAKE_ASM${ASM_DIALECT}_SOURCE_FILE_EXTENSIONS asm)
|
||||
|
||||
if(X64)
|
||||
list(APPEND ASM_FLAGS -DARCH_X86_64=1)
|
||||
if(ENABLE_PIC)
|
||||
list(APPEND ASM_FLAGS -DPIC)
|
||||
endif()
|
||||
if(APPLE)
|
||||
set(ARGS -f macho64 -m amd64 -DPREFIX)
|
||||
elseif(UNIX AND NOT CYGWIN)
|
||||
set(ARGS -f elf64 -m amd64)
|
||||
else()
|
||||
set(ARGS -f win64 -m amd64)
|
||||
endif()
|
||||
else()
|
||||
list(APPEND ASM_FLAGS -DARCH_X86_64=0)
|
||||
if(APPLE)
|
||||
set(ARGS -f macho -DPREFIX)
|
||||
elseif(UNIX AND NOT CYGWIN)
|
||||
set(ARGS -f elf32)
|
||||
else()
|
||||
set(ARGS -f win32 -DPREFIX)
|
||||
endif()
|
||||
endif()
|
||||
|
||||
if(GCC)
|
||||
list(APPEND ASM_FLAGS -DHAVE_ALIGNED_STACK=1)
|
||||
else()
|
||||
list(APPEND ASM_FLAGS -DHAVE_ALIGNED_STACK=0)
|
||||
endif()
|
||||
|
||||
if(HIGH_BIT_DEPTH)
|
||||
if(MAIN12)
|
||||
list(APPEND ASM_FLAGS -DHIGH_BIT_DEPTH=1 -DBIT_DEPTH=12 -DX265_NS=${X265_NS})
|
||||
else()
|
||||
list(APPEND ASM_FLAGS -DHIGH_BIT_DEPTH=1 -DBIT_DEPTH=10 -DX265_NS=${X265_NS})
|
||||
endif()
|
||||
else()
|
||||
list(APPEND ASM_FLAGS -DHIGH_BIT_DEPTH=0 -DBIT_DEPTH=8 -DX265_NS=${X265_NS})
|
||||
endif()
|
||||
|
||||
list(APPEND ASM_FLAGS "${CMAKE_ASM_YASM_FLAGS}")
|
||||
|
||||
if(CMAKE_BUILD_TYPE MATCHES Release)
|
||||
list(APPEND ASM_FLAGS "${CMAKE_ASM_YASM_FLAGS_RELEASE}")
|
||||
elseif(CMAKE_BUILD_TYPE MATCHES Debug)
|
||||
list(APPEND ASM_FLAGS "${CMAKE_ASM_YASM_FLAGS_DEBUG}")
|
||||
elseif(CMAKE_BUILD_TYPE MATCHES MinSizeRel)
|
||||
list(APPEND ASM_FLAGS "${CMAKE_ASM_YASM_FLAGS_MINSIZEREL}")
|
||||
elseif(CMAKE_BUILD_TYPE MATCHES RelWithDebInfo)
|
||||
list(APPEND ASM_FLAGS "${CMAKE_ASM_YASM_FLAGS_RELWITHDEBINFO}")
|
||||
endif()
|
||||
|
||||
set(YASM_FLAGS ${ARGS} ${ASM_FLAGS} PARENT_SCOPE)
|
||||
string(REPLACE ";" " " CMAKE_ASM_YASM_COMPILER_ARG1 "${ARGS}")
|
||||
|
||||
# This section exists to override the one in CMakeASMInformation.cmake
|
||||
# (the default Information file). This removes the <FLAGS>
|
||||
# thing so that your C compiler flags that have been set via
|
||||
# set_target_properties don't get passed to yasm and confuse it.
|
||||
if(NOT CMAKE_ASM${ASM_DIALECT}_COMPILE_OBJECT)
|
||||
string(REPLACE ";" " " STR_ASM_FLAGS "${ASM_FLAGS}")
|
||||
set(CMAKE_ASM${ASM_DIALECT}_COMPILE_OBJECT "<CMAKE_ASM${ASM_DIALECT}_COMPILER> ${STR_ASM_FLAGS} -o <OBJECT> <SOURCE>")
|
||||
endif()
|
||||
|
||||
include(CMakeASMInformation)
|
||||
set(ASM_DIALECT)
|
||||
5
x265/source/cmake/CMakeDetermineASM_YASMCompiler.cmake
Normal file
5
x265/source/cmake/CMakeDetermineASM_YASMCompiler.cmake
Normal file
|
|
@ -0,0 +1,5 @@
|
|||
set(ASM_DIALECT "_YASM")
|
||||
set(CMAKE_ASM${ASM_DIALECT}_COMPILER ${YASM_EXECUTABLE})
|
||||
set(CMAKE_ASM${ASM_DIALECT}_COMPILER_INIT ${_CMAKE_TOOLCHAIN_PREFIX}yasm)
|
||||
include(CMakeDetermineASMCompiler)
|
||||
set(ASM_DIALECT)
|
||||
3
x265/source/cmake/CMakeTestASM_YASMCompiler.cmake
Normal file
3
x265/source/cmake/CMakeTestASM_YASMCompiler.cmake
Normal file
|
|
@ -0,0 +1,3 @@
|
|||
set(ASM_DIALECT "_YASM")
|
||||
include(CMakeTestASMCompiler)
|
||||
set(ASM_DIALECT)
|
||||
43
x265/source/cmake/FindNuma.cmake
Normal file
43
x265/source/cmake/FindNuma.cmake
Normal file
|
|
@ -0,0 +1,43 @@
|
|||
# Module for locating libnuma
|
||||
#
|
||||
# Read-only variables:
|
||||
# NUMA_FOUND
|
||||
# Indicates that the library has been found.
|
||||
#
|
||||
# NUMA_INCLUDE_DIR
|
||||
# Points to the libnuma include directory.
|
||||
#
|
||||
# NUMA_LIBRARY_DIR
|
||||
# Points to the directory that contains the libraries.
|
||||
# The content of this variable can be passed to link_directories.
|
||||
#
|
||||
# NUMA_LIBRARY
|
||||
# Points to the libnuma that can be passed to target_link_libararies.
|
||||
#
|
||||
# Copyright (c) 2015 Steve Borho
|
||||
|
||||
include(FindPackageHandleStandardArgs)
|
||||
|
||||
find_path(NUMA_ROOT_DIR
|
||||
NAMES include/numa.h
|
||||
PATHS ENV NUMA_ROOT
|
||||
DOC "NUMA root directory")
|
||||
|
||||
find_path(NUMA_INCLUDE_DIR
|
||||
NAMES numa.h
|
||||
HINTS ${NUMA_ROOT_DIR}
|
||||
PATH_SUFFIXES include
|
||||
DOC "NUMA include directory")
|
||||
|
||||
find_library(NUMA_LIBRARY
|
||||
NAMES numa
|
||||
HINTS ${NUMA_ROOT_DIR}
|
||||
DOC "NUMA library")
|
||||
|
||||
if (NUMA_LIBRARY)
|
||||
get_filename_component(NUMA_LIBRARY_DIR ${NUMA_LIBRARY} PATH)
|
||||
endif()
|
||||
|
||||
mark_as_advanced(NUMA_INCLUDE_DIR NUMA_LIBRARY_DIR NUMA_LIBRARY)
|
||||
|
||||
find_package_handle_standard_args(NUMA REQUIRED_VARS NUMA_ROOT_DIR NUMA_INCLUDE_DIR NUMA_LIBRARY)
|
||||
126
x265/source/cmake/FindVLD.cmake
Normal file
126
x265/source/cmake/FindVLD.cmake
Normal file
|
|
@ -0,0 +1,126 @@
|
|||
# Module for locating Visual Leak Detector.
|
||||
#
|
||||
# Customizable variables:
|
||||
# VLD_ROOT_DIR
|
||||
# This variable points to the Visual Leak Detector root directory. By
|
||||
# default, the module looks for the installation directory by examining the
|
||||
# Program Files/Program Files (x86) folders and the VLDROOT environment
|
||||
# variable.
|
||||
#
|
||||
# Read-only variables:
|
||||
# VLD_FOUND
|
||||
# Indicates that the library has been found.
|
||||
#
|
||||
# VLD_INCLUDE_DIRS
|
||||
# Points to the Visual Leak Detector include directory.
|
||||
#
|
||||
# VLD_LIBRARY_DIRS
|
||||
# Points to the Visual Leak Detector directory that contains the libraries.
|
||||
# The content of this variable can be passed to link_directories.
|
||||
#
|
||||
# VLD_LIBRARIES
|
||||
# Points to the Visual Leak Detector libraries that can be passed to
|
||||
# target_link_libararies.
|
||||
#
|
||||
#
|
||||
# Copyright (c) 2012 Sergiu Dotenco
|
||||
#
|
||||
# Permission is hereby granted, free of charge, to any person obtaining a copy
|
||||
# of this software and associated documentation files (the "Software"), to deal
|
||||
# in the Software without restriction, including without limitation the rights
|
||||
# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
|
||||
# copies of the Software, and to permit persons to whom the Software is
|
||||
# furnished to do so, subject to the following conditions:
|
||||
#
|
||||
# The above copyright notice and this permission notice shall be included in all
|
||||
# copies or substantial portions of the Software.
|
||||
#
|
||||
# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
|
||||
# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
|
||||
# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
|
||||
# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
|
||||
# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
|
||||
# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
|
||||
# SOFTWARE.
|
||||
|
||||
INCLUDE (FindPackageHandleStandardArgs)
|
||||
|
||||
SET (_VLD_POSSIBLE_LIB_SUFFIXES lib)
|
||||
|
||||
# Version 2.0 uses vld_x86 and vld_x64 instead of simply vld as library names
|
||||
IF (CMAKE_SIZEOF_VOID_P EQUAL 4)
|
||||
LIST (APPEND _VLD_POSSIBLE_LIB_SUFFIXES lib/Win32)
|
||||
ELSEIF (CMAKE_SIZEOF_VOID_P EQUAL 8)
|
||||
LIST (APPEND _VLD_POSSIBLE_LIB_SUFFIXES lib/Win64)
|
||||
ENDIF (CMAKE_SIZEOF_VOID_P EQUAL 4)
|
||||
|
||||
SET (PFILES "ProgramFiles")
|
||||
SET (PFILES_X86 "ProgramFiles(x86)") # hack to avoid escaping issues in cmake 3.1
|
||||
|
||||
FIND_PATH (VLD_ROOT_DIR
|
||||
NAMES include/vld.h
|
||||
PATHS ENV VLDROOT
|
||||
"$ENV{PFILES}/Visual Leak Detector"
|
||||
"$ENV{PFILES_X86}/Visual Leak Detector"
|
||||
"[HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\Windows\\CurrentVersion\\Uninstall\\Visual Leak Detector;InstallLocation]"
|
||||
"[HKEY_LOCAL_MACHINE\\SOFTWARE\\Wow6432Node\\Microsoft\\Windows\\CurrentVersion\\Uninstall\\Visual Leak Detector;InstallLocation]"
|
||||
DOC "VLD root directory")
|
||||
|
||||
FIND_PATH (VLD_INCLUDE_DIR
|
||||
NAMES vld.h
|
||||
HINTS ${VLD_ROOT_DIR}
|
||||
PATH_SUFFIXES include
|
||||
DOC "VLD include directory")
|
||||
|
||||
FIND_LIBRARY (VLD_LIBRARY_DEBUG
|
||||
NAMES vld
|
||||
HINTS ${VLD_ROOT_DIR}
|
||||
PATH_SUFFIXES ${_VLD_POSSIBLE_LIB_SUFFIXES}
|
||||
DOC "VLD debug library")
|
||||
|
||||
IF (VLD_ROOT_DIR)
|
||||
SET (_VLD_VERSION_FILE ${VLD_ROOT_DIR}/CHANGES.txt)
|
||||
|
||||
IF (EXISTS ${_VLD_VERSION_FILE})
|
||||
SET (_VLD_VERSION_REGEX
|
||||
"Visual Leak Detector \\(VLD\\) Version (([0-9]+)\\.([0-9]+)([a-z]|(.([0-9]+)))?)")
|
||||
FILE (STRINGS ${_VLD_VERSION_FILE} _VLD_VERSION_TMP REGEX
|
||||
${_VLD_VERSION_REGEX})
|
||||
|
||||
STRING (REGEX REPLACE ${_VLD_VERSION_REGEX} "\\1" _VLD_VERSION_TMP
|
||||
"${_VLD_VERSION_TMP}")
|
||||
|
||||
STRING (REGEX REPLACE "([0-9]+).([0-9]+).*" "\\1" VLD_VERSION_MAJOR
|
||||
"${_VLD_VERSION_TMP}")
|
||||
STRING (REGEX REPLACE "([0-9]+).([0-9]+).*" "\\2" VLD_VERSION_MINOR
|
||||
"${_VLD_VERSION_TMP}")
|
||||
|
||||
SET (VLD_VERSION ${VLD_VERSION_MAJOR}.${VLD_VERSION_MINOR})
|
||||
|
||||
IF ("${_VLD_VERSION_TMP}" MATCHES "^([0-9]+).([0-9]+).([0-9]+)$")
|
||||
# major.minor.patch version numbering scheme
|
||||
STRING (REGEX REPLACE "([0-9]+).([0-9]+).([0-9]+)" "\\3"
|
||||
VLD_VERSION_PATCH "${_VLD_VERSION_TMP}")
|
||||
SET (VLD_VERSION "${VLD_VERSION}.${VLD_VERSION_PATCH}")
|
||||
SET (VLD_VERSION_COUNT 3)
|
||||
ELSE ("${_VLD_VERSION_TMP}" MATCHES "^([0-9]+).([0-9]+).([0-9]+)$")
|
||||
# major.minor version numbering scheme. The trailing letter is ignored.
|
||||
SET (VLD_VERSION_COUNT 2)
|
||||
ENDIF ("${_VLD_VERSION_TMP}" MATCHES "^([0-9]+).([0-9]+).([0-9]+)$")
|
||||
ENDIF (EXISTS ${_VLD_VERSION_FILE})
|
||||
ENDIF (VLD_ROOT_DIR)
|
||||
|
||||
IF (VLD_LIBRARY_DEBUG)
|
||||
SET (VLD_LIBRARY debug ${VLD_LIBRARY_DEBUG} CACHE DOC "VLD library")
|
||||
GET_FILENAME_COMPONENT (_VLD_LIBRARY_DIR ${VLD_LIBRARY_DEBUG} PATH)
|
||||
SET (VLD_LIBRARY_DIR ${_VLD_LIBRARY_DIR} CACHE PATH "VLD library directory")
|
||||
ENDIF (VLD_LIBRARY_DEBUG)
|
||||
|
||||
SET (VLD_INCLUDE_DIRS ${VLD_INCLUDE_DIR})
|
||||
SET (VLD_LIBRARY_DIRS ${VLD_LIBRARY_DIR})
|
||||
SET (VLD_LIBRARIES ${VLD_LIBRARY})
|
||||
|
||||
MARK_AS_ADVANCED (VLD_INCLUDE_DIR VLD_LIBRARY_DIR VLD_LIBRARY_DEBUG VLD_LIBRARY)
|
||||
|
||||
FIND_PACKAGE_HANDLE_STANDARD_ARGS (VLD REQUIRED_VARS VLD_ROOT_DIR
|
||||
VLD_INCLUDE_DIR VLD_LIBRARY VERSION_VAR VLD_VERSION)
|
||||
25
x265/source/cmake/FindYasm.cmake
Normal file
25
x265/source/cmake/FindYasm.cmake
Normal file
|
|
@ -0,0 +1,25 @@
|
|||
include(FindPackageHandleStandardArgs)
|
||||
|
||||
# Simple path search with YASM_ROOT environment variable override
|
||||
find_program(YASM_EXECUTABLE
|
||||
NAMES yasm yasm-1.2.0-win32 yasm-1.2.0-win64 yasm yasm-1.3.0-win32 yasm-1.3.0-win64
|
||||
HINTS $ENV{YASM_ROOT} ${YASM_ROOT}
|
||||
PATH_SUFFIXES bin
|
||||
)
|
||||
|
||||
if(YASM_EXECUTABLE)
|
||||
execute_process(COMMAND ${YASM_EXECUTABLE} --version
|
||||
OUTPUT_VARIABLE yasm_version
|
||||
ERROR_QUIET
|
||||
OUTPUT_STRIP_TRAILING_WHITESPACE
|
||||
)
|
||||
if(yasm_version MATCHES "^yasm ([0-9\\.]*)")
|
||||
set(YASM_VERSION_STRING "${CMAKE_MATCH_1}")
|
||||
endif()
|
||||
unset(yasm_version)
|
||||
endif()
|
||||
|
||||
# Provide standardized success/failure messages
|
||||
find_package_handle_standard_args(yasm
|
||||
REQUIRED_VARS YASM_EXECUTABLE
|
||||
VERSION_VAR YASM_VERSION_STRING)
|
||||
10
x265/source/cmake/clean-generated.cmake
Normal file
10
x265/source/cmake/clean-generated.cmake
Normal file
|
|
@ -0,0 +1,10 @@
|
|||
set(generated "${CMAKE_CURRENT_BINARY_DIR}/x265.rc"
|
||||
"${CMAKE_CURRENT_BINARY_DIR}/x265.pc"
|
||||
"${CMAKE_CURRENT_BINARY_DIR}/x265.def"
|
||||
"${CMAKE_CURRENT_BINARY_DIR}/x265_config.h")
|
||||
|
||||
foreach(file ${generated})
|
||||
if(EXISTS ${file})
|
||||
file(REMOVE ${file})
|
||||
endif()
|
||||
endforeach(file)
|
||||
19
x265/source/cmake/cmake_uninstall.cmake.in
Normal file
19
x265/source/cmake/cmake_uninstall.cmake.in
Normal file
|
|
@ -0,0 +1,19 @@
|
|||
if(NOT EXISTS "@CMAKE_CURRENT_BINARY_DIR@/install_manifest.txt")
|
||||
message(FATAL_ERROR "Cannot find install manifest: '@CMAKE_CURRENT_BINARY_DIR@/install_manifest.txt'")
|
||||
endif()
|
||||
|
||||
file(READ "@CMAKE_CURRENT_BINARY_DIR@/install_manifest.txt" files)
|
||||
string(REGEX REPLACE "\n" ";" files "${files}")
|
||||
foreach(file ${files})
|
||||
message(STATUS "Uninstalling $ENV{DESTDIR}${file}")
|
||||
if(EXISTS "$ENV{DESTDIR}${file}" OR IS_SYMLINK "$ENV{DESTDIR}${file}")
|
||||
exec_program("@CMAKE_COMMAND@" ARGS "-E remove \"$ENV{DESTDIR}${file}\""
|
||||
OUTPUT_VARIABLE rm_out
|
||||
RETURN_VALUE rm_retval)
|
||||
if(NOT "${rm_retval}" STREQUAL 0)
|
||||
message(FATAL_ERROR "Problem when removing '$ENV{DESTDIR}${file}'")
|
||||
endif(NOT "${rm_retval}" STREQUAL 0)
|
||||
else()
|
||||
message(STATUS "File '$ENV{DESTDIR}${file}' does not exist.")
|
||||
endif()
|
||||
endforeach(file)
|
||||
90
x265/source/cmake/version.cmake
Normal file
90
x265/source/cmake/version.cmake
Normal file
|
|
@ -0,0 +1,90 @@
|
|||
if(CMAKE_VERSION VERSION_LESS "2.8.10")
|
||||
find_program(HG_EXECUTABLE hg)
|
||||
else()
|
||||
find_package(Hg QUIET)
|
||||
endif()
|
||||
find_package(Git QUIET) # present in 2.8.8
|
||||
|
||||
# defaults, in case everything below fails
|
||||
set(X265_VERSION "unknown")
|
||||
set(X265_LATEST_TAG "0.0")
|
||||
set(X265_TAG_DISTANCE "0")
|
||||
|
||||
if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/../.hg_archival.txt)
|
||||
# read the lines of the archive summary file to extract the version
|
||||
file(READ ${CMAKE_CURRENT_SOURCE_DIR}/../.hg_archival.txt archive)
|
||||
STRING(REGEX REPLACE "\n" ";" archive "${archive}")
|
||||
foreach(f ${archive})
|
||||
string(FIND "${f}" ": " pos)
|
||||
string(SUBSTRING "${f}" 0 ${pos} key)
|
||||
string(SUBSTRING "${f}" ${pos} -1 value)
|
||||
string(SUBSTRING "${value}" 2 -1 value)
|
||||
set(hg_${key} ${value})
|
||||
endforeach()
|
||||
if(DEFINED hg_tag)
|
||||
set(X265_VERSION ${hg_tag})
|
||||
set(X265_LATEST_TAG ${hg_tag})
|
||||
set(X265_TAG_DISTANCE "0")
|
||||
elseif(DEFINED hg_node)
|
||||
string(SUBSTRING "${hg_node}" 0 16 hg_id)
|
||||
set(X265_VERSION "${hg_latesttag}+${hg_latesttagdistance}-${hg_id}")
|
||||
endif()
|
||||
elseif(HG_EXECUTABLE AND EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/../.hg)
|
||||
if(EXISTS "${HG_EXECUTABLE}.bat")
|
||||
# mercurial source installs on Windows require .bat extension
|
||||
set(HG_EXECUTABLE "${HG_EXECUTABLE}.bat")
|
||||
endif()
|
||||
message(STATUS "hg found at ${HG_EXECUTABLE}")
|
||||
|
||||
execute_process(COMMAND
|
||||
${HG_EXECUTABLE} log -r. --template "{latesttag}"
|
||||
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
|
||||
OUTPUT_VARIABLE X265_LATEST_TAG
|
||||
ERROR_QUIET
|
||||
OUTPUT_STRIP_TRAILING_WHITESPACE
|
||||
)
|
||||
execute_process(COMMAND
|
||||
${HG_EXECUTABLE} log -r. --template "{latesttagdistance}"
|
||||
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
|
||||
OUTPUT_VARIABLE X265_TAG_DISTANCE
|
||||
ERROR_QUIET
|
||||
OUTPUT_STRIP_TRAILING_WHITESPACE
|
||||
)
|
||||
execute_process(
|
||||
COMMAND
|
||||
${HG_EXECUTABLE} log -r. --template "{node|short}"
|
||||
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
|
||||
OUTPUT_VARIABLE HG_REVISION_ID
|
||||
ERROR_QUIET
|
||||
OUTPUT_STRIP_TRAILING_WHITESPACE
|
||||
)
|
||||
|
||||
if(X265_LATEST_TAG MATCHES "^r")
|
||||
string(SUBSTRING ${X265_LATEST_TAG} 1 -1 X265_LATEST_TAG)
|
||||
endif()
|
||||
if(X265_TAG_DISTANCE STREQUAL "0")
|
||||
set(X265_VERSION "${X265_LATEST_TAG}")
|
||||
else()
|
||||
set(X265_VERSION "${X265_LATEST_TAG}+${X265_TAG_DISTANCE}-${HG_REVISION_ID}")
|
||||
endif()
|
||||
elseif(GIT_EXECUTABLE AND EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/../.git)
|
||||
execute_process(
|
||||
COMMAND
|
||||
${GIT_EXECUTABLE} describe --tags --abbrev=0
|
||||
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
|
||||
OUTPUT_VARIABLE X265_LATEST_TAG
|
||||
ERROR_QUIET
|
||||
OUTPUT_STRIP_TRAILING_WHITESPACE
|
||||
)
|
||||
|
||||
execute_process(
|
||||
COMMAND
|
||||
${GIT_EXECUTABLE} describe --tags
|
||||
WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
|
||||
OUTPUT_VARIABLE X265_VERSION
|
||||
ERROR_QUIET
|
||||
OUTPUT_STRIP_TRAILING_WHITESPACE
|
||||
)
|
||||
endif()
|
||||
|
||||
message(STATUS "x265 version ${X265_VERSION}")
|
||||
Loading…
Add table
Add a link
Reference in a new issue