cpp = meson.get_compiler('cpp')
fslib_dep = cpp.find_library('stdc++fs', required: false)

qt6 = import('qt6')
qt6_dep = dependency('qt6', modules: ['Core', 'Gui', 'Widgets'], version: '>=5.15')
inc = include_directories('.')
moc_files = qt6.preprocess(
  moc_headers: [
    'memoserv_win.hpp',
    'version_info_win.hpp',
    'widgets/block_grid.hpp',
  ],
#ui_files: 'main_window.ui',
  moc_extra_arguments: ['-DMAKES_MY_MOC_HEADER_COMPILE'],
  include_directories: inc,
  dependencies: qt6_dep
)

app_name = meson.project_name() + '-qt'
conf = configuration_data()
conf.set('APP_NAME', app_name)
conf.set('APP_SHORT_DESC', 'PSX memory card inspector')
config_file = configure_file(
  input: app_config_model,
  output: 'app_config.h',
  configuration: conf
)

executable(app_name,
  'main.cpp',
  'memoserv_win.cpp',
  'version_info_win.cpp',
  moc_files,
  config_file,
  project_config_file,
  gitrev_config_file,
  'widgets/block_grid.cpp',
  'widgets/detail/block_drag_and_drop.cpp',
  'make_qt_animation.cpp',
  'animated_pixmap.cpp',
  'block_db.cpp',
  include_directories: inc,
  dependencies: [
    qt6_dep,
    fslib_dep,
    memcard_dep,
    vectorwrapper_dep
  ],
  install: true,
)