Change SQLiteCpp into a wrap file

subprojects/packagefiles/SQLiteCpp/meson.build

@@ -0,0 +1,43 @@
+project('SQLiteCpp', 'cpp',
+  version: '3.1.1',
+  meson_version: '>=0.49.2',
+  default_options: ['cpp_std=c++11'],
+)
+
+sqlite_dep = dependency('sqlite3', version: '>=3.32.1')
+
+pub_incdir = include_directories('SQLiteCpp/include')
+
+compiler_opts = []
+if get_option('sqlite_enable_column_metadata')
+  compiler_opts += ['-DSQLITE_ENABLE_COLUMN_METADATA']
+endif
+if get_option('sqlite_enable_assert_handler')
+  compiler_opts += ['SQLITECPP_ENABLE_ASSERT_HANDLER']
+endif
+if get_option('sqlite_has_codec')
+  compiler_opts += ['SQLITE_HAS_CODEC']
+endif
+if get_option('sqlite_use_legacy_struct')
+  compiler_opts += ['SQLITE_USE_LEGACY_STRUCT']
+endif
+
+sqlitecpp_target = library(meson.project_name(),
+  'SQLiteCpp/src/Backup.cpp',
+  'SQLiteCpp/src/Column.cpp',
+  'SQLiteCpp/src/Database.cpp',
+  'SQLiteCpp/src/Exception.cpp',
+  'SQLiteCpp/src/Statement.cpp',
+  'SQLiteCpp/src/Transaction.cpp',
+  install: true,
+  include_directories: [pub_incdir],
+  dependencies: [sqlite_dep],
+  c_args: compiler_opts,
+  cpp_args: compiler_opts,
+)
+
+sqlitecpp_dep = declare_dependency(
+  link_with: sqlitecpp_target,
+  include_directories: pub_incdir,
+  compile_args: compiler_opts,
+)

subprojects/packagefiles/SQLiteCpp/meson_options.txt

@@ -0,0 +1,27 @@
+option(
+  'sqlite_enable_column_metadata',
+  type: 'boolean',
+  value: true,
+  description: 'Enable Column::getColumnOriginName(). Require support from sqlite3 library.'
+)
+
+option(
+  'sqlite_enable_assert_handler',
+  value: false,
+  type: 'boolean',
+  description: 'Enable the user definition of a assertion_failed() handler.'
+)
+
+option(
+  'sqlite_has_codec',
+  value: false,
+  type: 'boolean',
+  description: 'Enable database encryption API. Not available in the public release of SQLite.'
+)
+
+option(
+  'sqlite_use_legacy_struct',
+  value: false,
+  type: 'boolean',
+  description: 'Fallback to forward declaration of legacy struct sqlite3_value (pre SQLite 3.19)'
+)