project('vectorwrapper', 'cpp',
	version: '1.1.2',
	meson_version: '>=0.50.0',
	default_options:['cpp_std=c++11', 'b_ndebug=if-release']
)

pkg = import('pkgconfig')

public_includes = include_directories('include')

subdir('include/vectorwrapper')

vectorwrapper_dep = declare_dependency(
	include_directories: [public_includes],
)

install_headers(
	'include/vectorwrapper/has_method.hpp',
	'include/vectorwrapper/implem_vec_base.hpp',
	'include/vectorwrapper/implem_vec_base.inl',
	'include/vectorwrapper/implem_vec_common.hpp',
	'include/vectorwrapper/sequence_bt.hpp',
	'include/vectorwrapper/sequence_range.hpp',
	'include/vectorwrapper/size_type.hpp',
	'include/vectorwrapper/vector_cast.hpp',
	'include/vectorwrapper/vectorops.hpp',
	'include/vectorwrapper/vector_ostream.hpp',
	'include/vectorwrapper/vectorwrapper.inl',
	project_config_file,
	subdir: 'vectorwrapper',
)

pkg.generate(
  name: meson.project_name(),
  description: 'A template vector wrapper class for C++',
  url: 'https://alarmpi.no-ip.org/gitan/King_DuckZ/vectorwrapper/',
  subdirs: ''
)

if get_option('build_testing')
	subdir('test')
endif
