mirror of
https://github.com/GTAmodding/re3.git
synced 2024-11-15 04:59:00 +00:00
95 lines
2.8 KiB
CMake
95 lines
2.8 KiB
CMake
cmake_minimum_required(VERSION 3.8)
|
|
|
|
project(re3 C CXX)
|
|
list(APPEND CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/cmake")
|
|
|
|
if(WIN32)
|
|
set(RE3_AUDIOS "OAL" "MSS")
|
|
else()
|
|
set(RE3_AUDIOS "OAL")
|
|
endif()
|
|
|
|
set(RE3_AUDIO "OAL" CACHE STRING "Audio")
|
|
|
|
option(RE3_WITH_OPUS "Build re3 with opus support" ON)
|
|
|
|
set_property(CACHE RE3_AUDIO PROPERTY STRINGS ${RE3_AUDIOS})
|
|
message(STATUS "RE3_AUDIO = ${RE3_AUDIO} (choices=${RE3_AUDIOS})")
|
|
set("RE3_AUDIO_${RE3_AUDIO}" ON)
|
|
if(NOT RE3_AUDIO IN_LIST RE3_AUDIOS)
|
|
message(FATAL_ERROR "Illegal RE3_AUDIO=${RE3_AUDIO}")
|
|
endif()
|
|
|
|
if(RE3_INSTALL)
|
|
include(GNUInstallDirs)
|
|
set(RE3_INSTALL_INCLUDEDIR "${CMAKE_INSTALL_INCLUDEDIR}/re3")
|
|
endif()
|
|
|
|
option(RE3_VENDORED_LIBRW "Use vendored librw" ON)
|
|
if(RE3_VENDORED_LIBRW)
|
|
add_subdirectory(vendor/librw)
|
|
else()
|
|
find_package(librw REQUIRED)
|
|
endif()
|
|
add_subdirectory(src)
|
|
|
|
if(RE3_INSTALL)
|
|
include(CMakePackageConfigHelpers)
|
|
configure_package_config_file(cmake/re3-config.cmake.in re3-config.cmake
|
|
INSTALL_DESTINATION "${CMAKE_INSTALL_PREFIX}"
|
|
)
|
|
install(
|
|
FILES "${CMAKE_CURRENT_BINARY_DIR}/re3-config.cmake"
|
|
DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}"
|
|
)
|
|
install(
|
|
EXPORT re3-targets
|
|
DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}"
|
|
)
|
|
|
|
if(LIBRW_PLATFORM_NULL)
|
|
set(platform "-null")
|
|
elseif(LIBRW_PLATFORM_PS2)
|
|
set(platform "-ps2")
|
|
elseif(LIBRW_PLATFORM_GL3)
|
|
if(LIBRW_GL3_GFXLIB STREQUAL "GLFW")
|
|
set(platform "-gl3-glfw")
|
|
else()
|
|
set(platform "-gl3-sdl2")
|
|
endif()
|
|
elseif(LIBRW_PLATFORM_D3D9)
|
|
set(platform "-d3d9")
|
|
endif()
|
|
if(RE3_AUDIO_OAL)
|
|
set(audio "-oal")
|
|
elseif(RE3_AUDIO_MSS)
|
|
set(audio "-mss")
|
|
endif()
|
|
if(RE3_WITH_OPUS)
|
|
set(audio "${audio}-opus")
|
|
endif()
|
|
if(NOT LIBRW_PLATFORM_PS2)
|
|
if(WIN32)
|
|
set(os "-win")
|
|
elseif(APPLE)
|
|
set(os "-apple")
|
|
elseif(UNIX)
|
|
set(os "-linux")
|
|
else()
|
|
set(compiler "-UNK")
|
|
message(WARNING "Unknown os. Created cpack package will be wrong. (override using cpack -P)")
|
|
endif()
|
|
endif()
|
|
|
|
set(CPACK_PACKAGE_NAME "${PROJECT_NAME}${platform}${audio}${os}${compiler}")
|
|
set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "GTA III reversed")
|
|
set(CPACK_PACKAGE_VENDOR "GTAModding")
|
|
# FIXME: missing license (https://github.com/GTAmodding/re3/issues/794)
|
|
# set(CPACK_PACKAGE_DESCRIPTION_FILE "${PROJECT_SOURCE_DIR}/LICENSE")
|
|
# set(CPACK_RESOURCE_FILE_LICENSE "${PROJECT_SOURCE_DIR}/LICENSE")
|
|
set(CPACK_PACKAGE_INSTALL_DIRECTORY "${CPACK_PACKAGE_NAME}")
|
|
set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}")
|
|
set(CPACK_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}")
|
|
set(CPACK_GENERATOR "TXZ")
|
|
include(CPack)
|
|
endif()
|